首页 > 汇编语言 > 汇编语言字符串和数组

汇编语言Irvine32字符串过程详解[附带实例]

< 上一页LODSB、LODSW和LODSD指令 Irivne64字符串过程下一页 >
本节将演示用 Irvine32 链接库中的几个过程来处理空字节结束的字符串。这些过程与标准 C 库中的函数有着明显的相似性：

;将源串复制到目的串。
Str_copy PROTO,
    source:PTR BYTE,
    target:PTR BYTE
;用 EAX 返回串长度（包括零字节）。
Str_length PROTO,
    pString:PTR BYTE
;比较字符串 1 和字符串 2。
;并用与 CMP 指令相同的方法设置零标志位和进位标志位。
Str_compare PROTO,
    string1:PTR BYTE,
    string2:PTR BYTE
;从字符串尾部去掉特定的字符。
;第二个参数为要去除的字符。
Str_trim PROTO,
    pString:PTR BYTE,
    char:BYTE
;将字符串转换为大写。
Str_ucase PROTO,
    pString:PTR BYTE

Str_compare 过程

Str_compare 过程比较两个字符串，其调用格式如下：

INVOKE Str_compare, ADDR string1, ADDR string2

它从第一个字节开始按正序比较字符串。这种比较是区分大小写的，因为字母的大写和小写 ASCII 码不相同。该过程没有返回值，若参数为 string1 和 string2，则进位标志位和零标志位的含义如下表所示。

关系 进位标志位 零标志位 为真则分支（指令）
string1 < string2 1 0 JB
string1 = string2 0 1 JE
string1 > string2 0 0 JA

回顾《CMP指令》一节中 CMP 指令如何设置进位标志位和零标志位。下面给出了 Str_compare 过程的代码清单。
  1. ;--------------------------------------
  2. Str_compare PROC USES eax edx esi edi,
  3.     string1:PTR BYTE,
  4.     string2:PTR BYTE
  5. ;比较两个字符串。
  6. ;无返回值，但是零标志位和进位标志位受到的影响与 CMP 指令相同。
  7. ;--------------------------------------
  8.     mov esi, string1
  9.     mov edi, string2
  10. L1: mov al, [esi]
  11.     mov dl, [edi]
  12.     cmp al, 0            ; string1 结束？
  13.     jne L2               ; 否
  14.     cmp dl, 0            ; 是：string2 结束？
  15.     jne L2               ; 否
  16.     jmp L3               ; 是，退出且ZF=1
  17. L2: inc esi              ; 指向下一个字符
  18.     inc edi              ; 字符相等？
  19.     cmp al,dl            ; 是：继续循环
  20.     je L1
  21. L3: ret                  ; 否：退出并设置标志位
  22. Str_compare ENDP
实现 Str_compare 时也可以使用 CMPSB 指令，但是这条指令要求知道较长字符串的长度，这样就需要调用 Str_length 程两次。

本例中，在同一个循环内检测两个字符串的零结束符显得更加容易。CMPSB 在处理长度已知的大型字符串或数组时最有效。

Str_length 过程

Str_length 过程用 EAX 返回一个字符串的长度。调用该过程时，要传递字符串的偏移地址。例如：

INVOKE Str_length, ADDR myString

过程实现如下：
  1. Str_length PROC USES edi,
  2.     pString:PTR BYTE       ;指向字符串
  3.     mov edi, pString       ;字符计数器
  4.     mov eax, 0             ;字符结束？
  5. L1: cmp BYTE PTR[edi],0
  6.     je L2                  ;是：退出
  7.     inc edi                ;否：指向下一个字符
  8.     inc eax                ;计数器加1
  9.     jmp L1
  10. L2: ret
  11. Str_length ENDP

Str_copy 过程

Str_copy 过程把一个空字节结束的字符串从源地址复制到目的地址。调用该过程之前，要确保目标操作数能够容纳被复制的字符串。Str_copy 的调用语法如下：

INVOKE Str_copy, ADDR source, ADDR target

过程无返回值。下面是其实现：
  1. ;--------------------------------------
  2. Str_copy PROC USES eax ecx esi edi,
  3.     source:PTR BYTE,       ; source string
  4.     target:PTR BYTE        ; target string
  5. ;将字符串从源串复制到目的串。
  6. ;要求：目标串必须有足够空间容纳从源复制来的串。
  7. ;--------------------------------------
  8.     INVOKE Str_length, source      ;EAX = 源串长度
  9.     mov ecx, eax                   ;重复计数器
  10.     inc    ecx                     ;由于有零字节，计数器加 1
  11.     mov esi, source
  12.     mov edi, target
  13.     cld                            ;方向为正向
  14.     rep    movsb                   ;复制字符串
  15.     ret
  16. Str_copy ENDP

Str_trim 过程

Str_trim 程从空字节结束字符串中移除所有与选定的尾部字符匹配的字符。其调用语法如下：

INVOKE Str_trim, ADDR string, char_to_trim

这个过程的逻辑很有意思，因为程序需要检查多种可能的情况（以下用 # 作为尾部字符）：

1) 字符串为空。

2) 字符串一个或多个尾部字符的前面有其他字符，如“Hello#”。

3) 字符串只含有一个字符，且为尾部字符，如“#”。

4) 字符串不含尾部字符，如“Hello”或“H”。

5) 字符串在一个或多个尾部字符后面跟随有一个或多个非尾部字符，如“#H”或“##Hello”

使用 Str_trim 过程可以删除字符串尾部的全部空格（或者任何重复的字符）。从字符串中去掉字符的最简单的方法是，在想要移除的字符前面插入一个空字节。空字节后面的任何字符都会变得无意义。

下表列出了一些有用的测试例子。在所有例子中都假设从字符串中删除的是 # 字符，表中给出了期望的输出。

输入字符串 预期修改后的字符串
“Hello##” “Hello”
“#” “”（空字符串）
“Hello”  "Hello”
“H” “H”
“#H” “#H”

现在来看看测试 Str_trim 程的代码。INVOKE 语句向 Str_trim 传递字符串地址：
  1. .data
  2. string_1 BYTE "Hello##",0
  3. .code
  4. INVOKE Str_trim,ADDR string_1,'#'
  5. INVOKE ShowString,ADDR string_1
ShowString 过程用方括号显示了被裁剪后的字符串，这里未给出其代码。过程输出示例如下：

[Hello]

下面给出了 Str_trim 的实现，它在想要保留的最后一个字符后面插入了一个空字节。空字节后面的任何字符一般都会被字符串处理函数所忽略。
  1. ;-------------------------------------
  2. ;Str_trim
  3. ;从字符串末尾删除所有与给定分隔符匹配的字符。
  4. ;返回：无
  5. ;-------------------------------------
  6. Str_trim PROC USES eax ecx edi,
  7.     pString:PTR BYTE,                ;指向字符串
  8.     char: BYTE                       ;要移必的字符
  9.     mov edi,pString                  ;准备调用 Str_length
  10.     INVOKE Str_length,edi            ;用 EAX 返回鬆
  11.     cmp eax,0                        ;长度是否为零？
  12.     je L3                            ;是：立刻退出
  13.     mov ecx, eax                     ;否：ECX = 字符串长度
  14.     dec eax
  15.     add edi,eax                      ;指向最后一个字符
  16. L1: mov al, [edi]                    ;取一个字符
  17.     cmp al,char                      ;是否为分隔符？
  18.     jne L2                           ;否：插入空字节
  19.     cec edi                          ;是：继续后退一个字符
  20.     loop L1                          ;直到字符串的第一个字符
  21. L2: mov BYTE PTR [edi+1 ],0          ;插入一个空字节
  22. L3:    ret
  23. Str_trim ENDP

详细说明

现在仔细研究一下 Str_trim。该算法从字符串最后一个字符开始，反向进行串扫描，以寻找第一个非分隔符字符。当找到这样的字符后，就在该字符后面的位置上插入一个空字节：
  1. ecx = length(str)
  2. if length (str) > 0 then
  3.     edi = length - 1
  4.     do while ecx > 0
  5.         if str[edi] ≠ delimiter then
  6.             str[edi+1] = null
  7.             break
  8.         else
  9.             edi = edi - 1
  10.         end if
  11.         ecx = ecx - 1
  12.     end do
下面逐行查看代码实现。首先，pString 为待裁剪字符串的地址。程序需要知道该字符串的长度，Str_length 过程用 EDI 寄存器接收其输入参数：

mov edi,pString              ;准备调用 Str_length
INVOKE Str_length,edi    ;过程返回值在 Eax 中

Str_length 过程用 EAX 寄存器返回字符串长度，所以，后面的代码行将它与零进行比较，如果字符串为空，则跳过后续代码：

cmp eax,0    ;字符串长度等于零吗？
je L3             ;是：立刻退出

在继续后面的程序之前，先假设该字符串不为空。ECX 为循环计数器，因此要将字符串长度赋给它。由于希望 EDI 指向字符串最后一个字符，因此把 EAX（包含字符串长度）减 1 后再加到 EDI 上：

mov ecx,eax          ;否：ECX =字符串长度
dec eax
add edi,eax           ;指向最后一个字符

现在 EDI 指向的是最后一个字符，将该字符复制到 AL 寄存器，并与分隔符比较：

L1: mov al, [edi]    ;取字符
    cmp al, char      ;是分隔符吗？

如果该字符不是分隔符，则退出循环，并用标号为 L2 的语句插入一个空字节：

jne L2                   ;否：插入空字节

否则，如果发现了分隔符，则继续循环，逆向搜索字符串。实现的方法为：将 EDI 后退一个字符，再重复循环：

dec edi                 ;是：继续后退
loop L1                ;直到字符串的第一个字符

如果整个字符串都由分隔符组成，则循环计数器将减到零，并继续执行 loop 指令下面的代码行，即标号为 L2 的代码，在字符串中插入一个空字节：

L2: mov BYTE PTR [edi+1], 0      ;插入空字节

假如程序控制到达这里的原因是循环计数减为零，那么，EDI 就会指向字符串第一个字符之前的位置。因此需要用表达式 [edi+1] 来指向第一个字符。

在两种情况下，程序会执行标号 L2：
  • 其一，在字符串中发现了非分隔符字符；
  • 其二， 循环计数减为零。

标号 L2 后面是标号为 L3 的 RET 指令，用来结束整个过程：

L3:    ret
Str_trim ENDP

Str_ucase 过程

Str_ucase 过程把一个字符串全部转换为大写字母，无返回值。调用过程时，要向其传 递字符串的偏移量：

INVOKE Str_ucase, ADDR myString

过程实现如下：
  1. ;---------------------------------
  2. ;Str_ucase
  3. ;将空字节结束的字符串转换为大写字母。
  4. ;返回：无
  5. ;---------------------------------
  6. Str_ucase PROC USES eax esi,
  7. pString:PTR BYTE
  8.     mov esi,pString
  9. L1:
  10.     mov al, [esi]           ;取字符
  11.     cmp al, 0               ;字符串是否结束？
  12.     je L3                   ;是：退出
  13.     cnp al, 'a'             ;小于"a" ？
  14.     jb L2
  15.     cnp al, 'z'             ;大于"z" ？
  16.     ja L2
  17.     and BYTE PTR [esi], 11011111b ;转换字符
  18. L2: inc esi                 ;下一个字符
  19.     jmp L1
  20. L3: ret
  21. Str_ucase ENDP

字符串演示程序

下面的 32 位程序演示了对 Irivne32 链接库中 Str_trim、Str_ucase、Str_compare 和 Str_length 过程的调用：
  1. ; String Library Demo    (StringDemo.asm)
  2. ; 该程序演示了链接库中字符串处理过程
  3. INCLUDE Irvine32.inc
  4.  
  5. .data
  6. string_1 BYTE "abcde////",0
  7. string_2 BYTE "ABCDE",0
  8. msg0     BYTE "string_1 in upper case: ",0
  9. msg1     BYTE "string1 and string2 are equal",0
  10. msg2     BYTE "string_1 is less than string_2",0
  11. msg3     BYTE "string_2 is less than string_1",0
  12. msg4     BYTE "Length of string_2 is ",0
  13. msg5     BYTE "string_1 after trimming: ",0
  14.  
  15. .code
  16. main PROC
  17.  
  18.     call trim_string
  19.     call upper_case
  20.     call compare_strings
  21.     call print_length
  22.  
  23.     exit
  24. main ENDP
  25.  
  26. trim_string PROC
  27. ; 从 string_1 删除尾部字符
  28.     INVOKE Str_trim, ADDR string_1,'/'
  29.     mov        edx,OFFSET msg5
  30.     call    WriteString
  31.     mov        edx,OFFSET string_1
  32.     call    WriteString
  33.     call    Crlf
  34.  
  35.     ret
  36. trim_string ENDP
  37.  
  38. upper_case PROC
  39. ; 将 string_1 转换为大写字母
  40.     mov        edx,OFFSET msg0
  41.     call    WriteString
  42.     INVOKE  Str_ucase, ADDR string_1
  43.     mov        edx,OFFSET string_1
  44.     call    WriteString
  45.     call    Crlf
  46.  
  47.     ret
  48. upper_case ENDP
  49.  
  50. compare_strings PROC
  51. ; 比较 string_1 和 string_2.
  52.     INVOKE Str_compare, ADDR string_1, ADDR string_2
  53.     .IF ZERO?
  54.     mov    edx,OFFSET msg1
  55.     .ELSEIF CARRY?
  56.     mov    edx,OFFSET msg2     ; string 1 小于...
  57.     .ELSE
  58.     mov    edx,OFFSET msg3     ; string 2 小于...
  59.     .ENDIF
  60.     call    WriteString
  61.     call    Crlf
  62.  
  63.     ret
  64. compare_strings  ENDP
  65.  
  66. print_length PROC
  67. ; 显示 string_2 的长度
  68.     mov        edx,OFFSET msg4
  69.     call    WriteString
  70.     INVOKE  Str_length, ADDR string_2
  71.     call    WriteDec
  72.     call    Crlf
  73.  
  74.     ret
  75. print_length ENDP
  76. END main
调用 Str_trim 过程从 string_1 删除尾部字符，调用 Str_ucase 过程将字符串转换为大写字母。

String Library Demo 程序的输出如下所示：

< 上一页LODSB、LODSW和LODSD指令 Irivne64字符串过程下一页 >